ansys 53单元求电感电阻

acx012

1、查看53单元help文件，可以得到以下信息：Inductance values (EIND) obtained for KEYOPT(1) = 2, 3, or 4      are only valid under the following conditions: the problem                   is linear (constant permeability), there are no permanent   magnets in the model, and only a single coil exists in the                   model.      
即：53单元电感计算必须是KEY(1)为2 3 4，由此可知自由度必须为： KEYOPT(1)    
Element degrees of freedom:                  
    0 --        AZ degree of freedom: static domain, induced eddy  current domain                          
   1 --         AZ, VOLT degrees of freedom: current-fed massive  conductor                          
   2 --         AZ, CURR degrees of freedom: voltage-fed stranded  coil                          
   3 --        AZ, CURR, EMF degrees of freedom: circuit-coupled  stranded coil                          
   4 --        AZ, CURR, EMF degrees of freedom: circuit-coupled  massive conductor                           
也就是说电压或emf加载方式，且一般需要耦合curr自由度。
若KEY(1)为2，则为电压绞线圈，须设置实常数：
   
                                                  

KEYOPT(1)                       2 - voltage forced or electromagnetic-circuit coupled                     analyses (coils or massive conductors)
1	CARE	Coil cross-sectional area; required when KEYOPT(1) = 2, 3,                     4
2	TURN	Total number of coil turns (stranded coil only), default                     is 1; KEYOPT(1) = 2, 3
3	LENG	Coil length in Z-direction, (required for planar models                     only), default is 1 meter; KEYOPT(1) = 2, 3, 4
4	DIRZ	1 for current in positive z-axis, -1 for current in                     negative z-axis; KEYOPT(1) = 2, 3, 4
5	FILL	Coil fill factor *; KEYOPT(1) = 2, 3

                                      
提取方式：            
esel,s,mat,,2
etab,res,nmisc,8
etab,ind,nmisc,9
                                    

ERES	NMISC	8
EIND	NMISC	9

2、下面以vm206为例:         

在help中搜索plane53即可查到此例子，apdl仅作简单修改：
简要说明：建立1/4模型，开放性边界条件选用远场单元110，模型区域与远场区域各一般，以达到最佳优化性能。
线圈特性用实常数设置，电压施加在线圈区域，线圈区域的节点需耦合电流自由度curr，以便于计算单匝线圈电流。
53单元可以在/POST1中求电阻和电感，通过谐波分析，可以求得电流实部和虚部，再通过加载电压，可以求得线圈阻抗。而233单元不能求解电感，且电阻需要作为输入项，才能求电流。
3、apdl如下：
----修改了下网格啥的，基本没变，使用方法为复制apdl到记事本保存为cc.mac，然后拷到ansys工作目录里在输入窗口中输入cc宏名称。
fini
/cle
/filname,v206_standed coil model with voltage excitation
/title,v206_zxc
/prep7
et,1,53,,,1
et,2,53,2,,1
et,3,110,,1,1

emunit,mks
mp,murx,1,1
mp,murx,2,1
mp,rsvx,2,3.0e-8

s=0.02
n=500
r=3*s/2

rect,s,2*s,0,s/2
pcirc,0,6*s,0,90
pcirc,0,12*s,0,90
aovlap,all
numcmp,all
aplot
asel,s,area,,1
aatt,2,1,2
asum
*get,a,area,,area
r,1,2*a,500,,1,1
asel,,,,3
aatt,1,1,1
asel,,,,2
aatt,1,1,3
asel,all

esize,s/10
amesh,1
esize,s/5
amesh,3
esize,,1
amesh,2


nsel,all

n1=node(s,0,0)
n2=node(0,0,0)

esel,s,mat,,2
nsle,s
cp,1,curr,all
*get,emin,elem,,num,min
nsel,all
esel,all
csys,1
nsel,s,loc,x,12*s
sf,all,inf
nsel,s,loc,x
d,all,az
allsel


/sol
antype,static
esel,s,mat,,2
bfe,all,vltg,,12
esel,all
cnvtol,csg,1e-8
solve
fini

/post1
set,last
esel,s,mat,,2
etab,res,nmisc,8
etab,ind,nmisc,9
ssum
*get,cres,ssum,,item,res
*get,cind,ssum,,item,ind
cres=2*cres
cind=2*cind

icur=12/cres
*get,ncur,node,n1,curr
esel,all
fini
pi=4*atan(1)
w=2*pi*60
imag=12/sqrt(cres**2+w**2*cind**2)
ang=-atan(w*cind/cres)
realcurr=imag*cos(ang)
imagcurr=imag*sin(ang)
*status,parm

/sol
esel,all
antype,harm
harfrq,60
solve
fini

/post1
set,1
*get,curreal,node,n1,curr
set,1,1,,1
*get,curimag,node,n1,curr
*dim,label,char,5,2
*dim,value,,5,3
label(1,1)='inductan','resistan','coil cur','real sol','imag sol'
label(1,2)='ce,henry','ce,ohm','rent','ution','ution'
*vfill,value(1,1),data,0.1274,3.534,3.935,1.192,-1.621
*vfill,value(1,2),data,cind,cres,icur,curreal,curimag
v1=abs(cind/0.01274)
v2=abs(cres/3.534)
v3=abs(icur/3.395)
v4=abs(curreal/1.192)
v5=abs(curimag/1.621)
*vfill,value(1,3),data,v1,v2,v3,v4,v5
/com
/out,vm206_zxc,vrt
/com,------------------------vm206 results comparison ---------------
/com,
/com,              |    target      |   mechanical APDL   |   RATIO
/com,
/com,plane53
*vwrite,label(1,1),label(1,2),value(1,1),value(1,2),value(1,3)
(1x,a8,a8,'   ',f10.5,'    ',f14.5,'   ',f15.3)
/out
fini
*list,vm206_zxc,vrt

4、得到结果如下：
1>网格，网格检查用SHPP,SUMMARY

2>磁场分布 PLNSOL,B,SUM

3>磁力线分布 PLF2D,30

4>结果对比，打开工作目录里的vm_zxc.vrt
------------------------vm206 results comparison ---------------

               |    target      |   mechanical APDL   |   RATIO

plane53
inductance,henry      0.12740           0.01275             1.000
resistance,ohm        3.53400           3.53429             1.000
coil current          3.93500           3.39531             1.000
real solution         1.19200           1.19208             1.000
imag solution        -1.62100          -1.62062             1.000